AT93C46匯編讀寫示例程序; 說明: 軟件包僅適用于93C46 8位存儲器結(jié)構(gòu)狀態(tài),軟件包可嵌入到80C51 ROM中任一空間。 
; fosc = 12MHz 
;---------------------------------------------------------- 
    R31    EQU    1FH 

    CS    EQU    P1.0    ;片選端 
    SK    EQU    P1.1    ;模擬時(shí)鐘信號輸出端 
    DI    EQU    P1.2    ;串行數(shù)據(jù)輸出端 
    DO    EQU    P1.3    ;串行數(shù)據(jù)輸入端 
;---------------------------------------------------------- 
    ORG    0000H 
    JMP    MAIN 

    ORG    0100H 
MAIN: 
    MOV    R0,#7FH 
    CLR    A 
    MOV    @R0,A 
    DJNZ    R0,$-2 
    MOV    SP,#60H 
MAIN1: 
    MOV    R0,#30H 
    MOV    R7,#16 
    MOV    A,#1 
    MOV    @R0,A 
    INC    R0 
    INC    A 
    DJNZ    R7,$-3 
             
    CALL    EWNE        ;擦寫允許 
    MOV    A,#01100000B    ;地址"11xxxxx" 
    CALL    INADR        ;輸出地址 
     
    CALL    EWNE        ;片擦除(將整個(gè)存儲器置為"1") 
    MOV    A,#01000000B    ;片擦除地址 
    CALL    INADREW        ;輸出地址         
    CALL    DLY10ms     
     
    CALL    RD16        ;讀指定地址單元的數(shù)據(jù) 
             
    CALL    WRITE        ;將數(shù)據(jù)寫入指定地址單元 
     
    CALL    ERASE        ;擦除(將指定地址單元置為"1")     
    MOV    A,#01H        ;地址 
    CALL    INADREW        ;輸出地址         
    CALL    DLY10ms 
     
    CALL    RD16        ;讀 
     
    CALL    EWNE        ;擦/寫禁止 
    MOV    A,#0        ;地址"00xxxxx" 
    CALL    INADR        ;輸出地址 
         
    JMP    MAIN1 
;========================================================== 
;---------------------------------------------------------- 
;將存在80C51內(nèi)RAM 30H為首地址的16字節(jié)數(shù)據(jù)依次寫入93C46首址00H的EEPROM 
;注意: 93C46上電復(fù)位后,芯片處于寫保護(hù)狀態(tài),所以在擦寫操作前,應(yīng)開啟"寫允許". 
;否則無法寫入數(shù)據(jù). 

WRITE:     
    MOV    A,#01100000B    ;地址"11xxxxx" 
    CALL    INADR        ;輸出地址     
    MOV    R0,#30H        ;置源數(shù)據(jù)區(qū)首址 
    MOV    R1,#00H        ;置93C46寫入單元首址 
    MOV    R7,#16        ;字節(jié)數(shù) 
    CALL    WRIT6     
    RET 
;---------------------------------------------------------- 
;將AT93C46 首址為00H的16字節(jié)數(shù)據(jù)讀出并存入80C51以30H為首址的內(nèi)RAM中 

RD16:    MOV    R0,#20H        ;置數(shù)據(jù)存儲區(qū)首址 
    MOV    A,#00H        ;置93C46讀出單元首地址     
    MOV    R7,#16        ;字節(jié)數(shù)送R7 
    LCALL    STATRD        ;啟動讀 
    LCALL    INADR        ;輸出93C46讀出單元首址 
RD160:     
    LCALL    READ        ;讀出一個(gè)字節(jié)數(shù)據(jù) 
    MOV    @R0,A        ;存一個(gè)字節(jié)數(shù)據(jù) 
    INC    R0        ;指向下一存儲單元地址 
    DJNZ    R7,RD160    ;判16字節(jié)數(shù)據(jù)讀完否?未完繼續(xù) 
    CLR    CS        ;16字節(jié)數(shù)據(jù)讀完,置93C46低功耗備用狀態(tài) 
    CALL    DLY10ms        ;延時(shí)10ms,以便進(jìn)行芯片的其它功能操作 
    RET 
;---------------------------------------------------------- 
;入口: 數(shù)據(jù)區(qū)首址在R0,93C46單元地址在R1,寫入的字節(jié)數(shù)在R7中 
     
WRIT6:             
    LCALL    STATWR        ;啟動寫 
    MOV    A,R1        ;置93C46寫入單元地址 
    LCALL    INADR        ;輸出93C46寫入地址單元 
    MOV    A,@R0        ;讀寫入數(shù)據(jù) 
    LCALL    WRIT        ;寫入一個(gè)字節(jié)     
    LCALL    DLY1ms        ;延時(shí)1ms 
    INC    R0        ;指向8051下一個(gè)數(shù)據(jù)地址 
    INC    R1        ;指向93C46下一個(gè)寫入單元地址 
    DJNZ    R7,WR61        ;判6字節(jié)數(shù)據(jù)寫完否?未完繼續(xù)     
    CLR    CS        ;93C46進(jìn)入備用狀態(tài),降低功耗 
    CALL    DLY10ms 
    RET 
WR61:    JB    DO,WRIT6    ;判REDAY/BUSY,DO=1,寫入下一字節(jié) 
    SJMP    WR61        ;DO=0,轉(zhuǎn)等待 

;========================================================== 
; 啟動讀子程序 
; 說明: STATRD子程序輸出啟動和讀操作代碼"110" 
;---------------------------------------------------------- 
STATRD: 
    CLR    CS    ;片選置低 
    CLR    SK    ;時(shí)鐘置低 
    SETB    CS     
    SETB    DI    ;置啟動"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出啟動信號"1" 
    CLR    SK 
    SETB    SK    ;時(shí)鐘上升沿輸出"1" 
    CLR    SK 
    CLR    DI    ;置輸出"0" 
    SETB    SK    ;時(shí)鐘上升沿輸出"0" 
    CLR    SK    ;時(shí)鐘置低 
    RET 
;----------------------------------------------------------     
; 啟動寫子程序 
; 說明: STATWR子程序輸出啟動和寫操作代碼"101" 
;---------------------------------------------------------- 
STATWR: 
    CLR    CS    ;片選置低 
    CLR    SK    ;時(shí)鐘置低 
    SETB    CS    ;置片選 
    SETB    DI    ;置啟動"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出啟動信號"1" 
    CLR    SK 
    CLR    DI    ;置輸出"0" 
    SETB    SK    ;時(shí)鐘上升沿輸出"0" 
    CLR    SK 
    SETB    DI    ;置輸出"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出"1" 
    CLR    SK    ;時(shí)鐘置低 
    RET 
;---------------------------------------------------------- 
; 擦寫允許/禁止啟動和操作代碼 "100" 
; 該子程序可用于: 擦寫允許(EWEN)、寫禁止(EWDS)、片寫(WRAL)、片擦除(ERAL), 
; 只是各自的地址不同而也. 
; 擦寫允許/禁止操作代碼"100",地址"11xxxxx"/"00xxxxx" 
;---------------------------------------------------------- 
EWNE:         
    CLR    CS    ;片選置低 
    CLR    SK    ;時(shí)鐘置低 
    SETB    CS    ;置片選 
    SETB    DI    ;置啟動"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出啟動信號"1" 
    CLR    SK 
    CLR    DI    ;置輸出"0" 
    SETB    SK    ;時(shí)鐘上升沿輸出"0" 
    CLR    SK 
    CLR    DI    ;置輸出"0" 
    SETB    SK    ;時(shí)鐘上升沿輸出"1" 
    CLR    SK    ;時(shí)鐘置低 
    RET 
;---------------------------------------------------------- 
; 擦指令ERASE  啟動和操作代碼 "111" 
;---------------------------------------------------------- 
ERASE:         
    CLR    CS    ;片選置低 
    CLR    SK    ;時(shí)鐘置低 
    SETB    CS    ;置片選 
    SETB    DI    ;置啟動"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出啟動信號"1" 
    CLR    SK 
    SETB    DI    ;置輸出"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出"0" 
    CLR    SK 
    SETB    DI    ;置輸出"1" 
    SETB    SK    ;時(shí)鐘上升沿輸出"1" 
    CLR    SK    ;時(shí)鐘置低 
    RET 
;----------------------------------------------------------     
; 輸出讀寫單元地址子程序 
; 入口: 7位地址已存在A中D6~D0 
;---------------------------------------------------------- 
INADR: 
    MOV    R2,#7    ;置寫入地址位數(shù)(存儲單元8位結(jié)構(gòu)時(shí),地址為7位) 
    RLC    A    ;先左移一位,地址移至D7~D1,D0無效 
IR1:    CLR    SK    ;時(shí)鐘置低 
    RLC    A    ;左移一位 
    MOV    DI,C    ;存入DI端口 
    SETB    SK    ;時(shí)鐘上升沿輸出至93C46DI端 
    DJNZ    R2,IR1    ;判斷7位地址寫完否,未完繼續(xù)     
    RET 
;---------------------------------------------------------- 
; 輸出擦單元地址子程序 

INADREW: 
    CALL    INADR 
    CLR    CS 
    NOP 
    SETB    CS 
    JNB    DO,$    ; DO=0,表示編程正在進(jìn)行; 
            ; DO=1,表示該指定地址的寄存器單元已擦完,可以執(zhí)行下一條指令。 
    RET 
;---------------------------------------------------------- 
; 讀一個(gè)字節(jié)子程序 
; 出口: 8位數(shù)據(jù)存在A中 
;---------------------------------------------------------- 
READ:    CLR    SK    ;時(shí)鐘置低 
    MOV    R2,#8    ;置讀入位數(shù)8 
RD1:    SETB    SK    ;時(shí)鐘上升沿讀入一位數(shù)據(jù) 
    NOP 
    MOV    C,DO    ;存入Cy 
    RLC    A    ;左移入A中     
    CLR    SK    ;時(shí)鐘置低     
    DJNZ    R2,RD1    ;判8位數(shù)據(jù)讀完否?未完繼續(xù) 
    RET 
;---------------------------------------------------------- 
;確良寫一個(gè)字節(jié)子程序 
; 入口: 寫入數(shù)據(jù)須事先存入A中. 
; 若需寫入多個(gè)字節(jié)數(shù)據(jù),須在1ms后,93C46 DO 端出現(xiàn)高電平后才能重新啟動寫入. 
;---------------------------------------------------------- 
WRIT:     
    MOV    R2,#8    ;置寫入位數(shù)8 
WR1:    CLR    SK    ;時(shí)鐘置低 
    RLC    A    ;A中數(shù)據(jù)移一位至Cy中 
    MOV    DI,C    ;數(shù)據(jù)傳送至DI端 
    nop 
    SETB    SK    ;時(shí)鐘上升沿輸出至93C46 
    DJNZ    R2,WR1    ;判8位數(shù)據(jù)寫完否?未完繼續(xù) 
    CLR    CS    ;8位數(shù)據(jù)寫完,CS下降沿啟動93C46擦寫 
    SETB    CS    ;CS次高位,以使DO端REDAY/BUSY狀態(tài)位號有效 
    RET 
;---------------------------------------------------------- 
DLY1ms:                ;延時(shí)1ms子程序 
    MOV    R31,#29        ; 
L2:    PUSH    R31 
L3:    DJNZ    R31,L3 
    POP    R31 
    DJNZ    R31,L2          
    RET 
DLY10ms:            ;延時(shí)10ms子程序 
    MOV    R31,#100     
L20:    PUSH    R31 
L30:    DJNZ    R31,L30 
    POP    R31 
    DJNZ    R31,L20          
    RET 
;========================================================== 
END