AT93C46/56/57/66 EEPROM 芯片通用讀寫程序

; 模塊包含: READ(讀), WRITE(寫), WRAL(片寫), ERASE(擦除), ERAL(片擦除), 
; EWEN(擦寫允許), EWDS(擦寫禁止). 
; 此模塊適用于: AT93C46/56/57/66 EEPROM 芯片, 8位(ORG=0)或16位(ORG=1)的讀、寫、

; 擦除等操作。 
; 8位或16操作,只需置標(biāo)志位SIZE為"0"或?yàn)?1"和設(shè)置NADDR的位即可,非常方便實(shí)用。 
;           93C46       93C56       93C57       93C66 
;---------------------------------------------------------------------------- 
; Data bits:    8    16    8    16    8    16    8    16 
; Address bits:    7    6    9    8    8    7    9    8 
;---------------------------------------------------------------------------- 

NADDR        EQU    7    ;  8-bit data,地址為7位 
;NADDR        EQU    6    ;  16-bit data,地址為6位 


SIZE        EQU    F0    ; 0 = 8-bit data, 1 = 16-bit data 標(biāo)志位 

DATA_LO        EQU    2AH    ; 數(shù)據(jù)低字節(jié) 
DATA_HI        EQU    2BH    ; 數(shù)據(jù)高字節(jié) 
ADDR_LO        EQU    2CH    ; 地址低字節(jié) 
ADDR_HI        EQU    2DH    ; 地址高字節(jié) 

DATA01        EQU    30H    ;數(shù)據(jù)緩存區(qū)首址 

CS    BIT    P1.0        ; AT93Cxx 片選端 
SK    BIT    P1.1        ; 時(shí)鐘信號(hào)輸入端 
DI    BIT    P1.2        ; 串行數(shù)據(jù)輸入端 
DO    BIT    P1.3        ; 串行數(shù)據(jù)輸出端 

    DSEG AT 20H 

    ORG    60H        ; stack origin 
STACK:    DS    20H        ; stack depth 
    CSEG 
    ORG    0000H        ; 
    JMP    ON_RESET 
    ORG    0003H         
    reti             
    ORG    000BH         
    reti             
    ORG    0013H         
    reti             
    ORG    001BH         
    reti             
    ORG    0023H         
    reti             
    ORG    0080H         
    USING    0        ;選擇工作寄存器0         
ON_RESET: 
    MOV    SP, #(STACK-1)     

    CLR    CS        ; LOW 
    CLR    SK        ; LOW 
    SETB    DI        ; HIGH 
    SETB    DO        ; HIGH         

    CLR    SIZE        ; SPECIFY 8-BIT DATA 
;    SETB    SIZE        ; SPECIFY 16-BIT DATA 
     
    JB    SIZE,DATA16    ;SIZE=1時(shí),為16-bit操作 
    AJMP    DATA8 
;========================================================== 
; 8-bit  Byte (SIZE/ORG=0) 程序操作演示     

DATA8: 
    CALL    Byte_read    ;讀出數(shù)據(jù),以便觀察 
     
    CALL    EWEN        ;擦寫允許 
     
    MOV    ADDR_LO, #0    ; 地址 
    MOV    DATA_LO, #33H    ; 數(shù)據(jù) 
    CALL    WRITE        ; 指定地址寫 
     
    CALL    Byte_read 
     
    CALL    ERAL        ;片擦除 (全部單元置"1")     

    CALL    Byte_read 

; 8-bit 片寫,將芯存儲(chǔ)器全部寫入55H的數(shù)據(jù) 

;    CALL    EWDS        ; 擦寫禁止 

    MOV    DATA_LO, #55H    ; 片寫數(shù)據(jù)(片寫之前最好片擦除) 
    CALL    WRAL        ; 片寫         

    AJMP    DATA8 
;========================================================== 
;========================================================== 
; 16-bit  Word (SIZE/ORG=1) 程序操作演示 

DATA16: 
    CALL    Word_read    ;讀8個(gè)單元數(shù)據(jù),觀察 
         
    CALL    EWEN        ;擦寫允許 
     
    CALL    ERAL        ;片擦除 (全部單元置"1")     
     
    CALL    Word_read 
     
    MOV    ADDR_LO, #0    ; 向指定地址寫數(shù)據(jù) 
    MOV    DATA_LO, #55H    ; DATA,數(shù)據(jù)低字節(jié) 
    MOV    DATA_HI, #0AAH    ; DATA,數(shù)據(jù)高字節(jié) 
    CALL    WRITE        ; 指定地址寫 
     
    CALL    Word_read 

; 將芯片存儲(chǔ)器全部寫入0AAH(高)和55H(低)的數(shù)據(jù)  

    MOV    DATA_LO, #55H    ; DATA 
    MOV    DATA_HI, #0AAH    ; DATA 
    CALL    WRAL        ;  

    CALL    Word_read 

;    CALL    EWDS        ; 擦寫禁止 

; 將指定單元的內(nèi)容擦除(置為"1")     
    MOV    ADDR_LO, #0    ;  
    CALL    ERASE        ; 將指定單元(00H 01H)擦為"1" 
         
    AJMP    DATA16 
;========================================================== 
;讀 Read (byte if SIZE/ORG=0, word if SIZE/ORG=1). 
Byte_read:     
    MOV    R0,#DATA01    ;緩存區(qū)首址 
    MOV    ADDR_HI,#0 
    MOV    ADDR_LO,#0    ;指向AT93CXX首址 
    MOV    R7,#8        ;字節(jié)數(shù) 
READ01:             
    CALL    READ 
    MOV    A,DATA_LO 
    MOV    @R0,A 
    INC    R0 
    INC    ADDR_LO 
    DJNZ    R7,READ01 
    RET     
;========================================================== 
;讀 Read ( word if SIZE/ORG=1).低地址為低字節(jié)單元,高地址為高字節(jié)單元 
Word_read:     
    MOV    R0,#DATA01    ;緩存區(qū)首址 
    MOV    ADDR_LO,#0 
    MOV    R7,#8        ;字節(jié)數(shù) 
WORD01:     
    CALL    READ        ;讀數(shù)據(jù) 
    MOV    A,DATA_LO    ;低字節(jié)內(nèi)容 
    MOV    @R0,A     
    INC    R0 
    MOV    A,DATA_HI    ;高字節(jié)內(nèi)容 
    MOV    @R0,A 
    INC    R0 
    INC    ADDR_LO         
    DJNZ    R7,WORD01 
    RET     
;---------------------------------------------------------- 
;========================================================== 
;名稱: 讀指令(READ指令) 
;功能: 從指定的地址單元中把數(shù)據(jù)讀出 
;---------------------------------------------------------- 
READ: 
    SETB    CS        ;片選置1     
    MOV    DPL, #110B    ;起始位和操作碼"110" 
    MOV    B, #3 
    CALL    OUTDATA         
    MOV    DPL,ADDR_LO    ;低字節(jié)地址 
    MOV    DPH,ADDR_HI    ;高字節(jié)地址 
    MOV    B,#NADDR    ;地址位數(shù)(8-bit data,NADDR=7) 
    CALL    OUTDATA        ;輸出讀/寫單元地址         
    CALL    INDATA         
    CLR    CS         
    RET 
;========================================================== 
;名稱: 寫指令(WRITE 指令) 
;功能: 將數(shù)據(jù)寫入到指定的地址單元中 
;---------------------------------------------------------- 
WRITE: 
    SETB    CS        ;     
    MOV    DPL, #101B    ;起始位和操作碼"101B" 
    MOV    B, #3        ;位數(shù) 
    CALL    OUTDATA        ;輸出數(shù)據(jù) 
    MOV    DPL, ADDR_LO     
    MOV    DPH, ADDR_HI     
    MOV    B, #NADDR     
    CALL    OUTDATA     
    MOV    DPL, DATA_LO     
    JB    SIZE, EE61    ;SIZE=0時(shí),8bit; SIZE=1時(shí),16bit; 
    MOV    B, #8 
    JMP    EE62 
EE61: 
    MOV    DPH, DATA_HI     
    MOV    B, #16 
EE62: 
    CALL    OUTDATA 
    CLR    CS             
    CALL    STATUS        ; 延時(shí)10ms 
    RET 
;========================================================== 
;名稱: 片寫指令(WRAL 指令) 
;功能: 將命令中指定的數(shù)據(jù)寫入整個(gè)存貯器陣列 
;---------------------------------------------------------- 
WRAL:     
    SETB    CS        ;片選置1,選中芯片     
    MOV    DPTR, #(10001B SHL (NADDR-2)) 
    MOV    B, #(NADDR+3) 
    CALL    OUTDATA         
    MOV    DPL, DATA_LO 
    JB    SIZE, EE71    ; SIZE=0時(shí),8bit; SIZE=1時(shí),16bit; 
    MOV    B, #8 
    JMP    EE72 
EE71: 
    MOV    DPH, DATA_HI 
    MOV    B, #16 
EE72: 
    CALL    OUTDATA 
    CLR    CS         
    CALL    STATUS        ; 延時(shí)10ms 
    RET 
;========================================================== 
;名稱: 地址擦指令(ERASE 指令) 
;功能: 將指定地址中所有數(shù)據(jù)位都為置為"1" 
;---------------------------------------------------------- 
ERASE: 
    SETB    CS                 
    MOV    DPTR, #111B    ;擦除指令操作碼"111B" 
    MOV    B, #3 
    CALL    OUTDATA                 
    MOV    DPL, ADDR_LO    ;地址低位 
    MOV    DPH, ADDR_HI    ;地址高位 
    MOV    B, #NADDR    ; 
    CALL    OUTDATA 
    CLR    CS                         
    CALL    STATUS        ; 延時(shí)10ms 
    RET 
;========================================================== 
;名稱: 片擦指令(ERAL 指令) ,  
;功能: 將整個(gè)存儲(chǔ)器陣列置為"1" 
;---------------------------------------------------------- 
ERAL: 
    SETB    CS                         
    MOV    DPTR, #(10010B SHL (NADDR-2))    ;左移 
                ; ERAL指令 操作碼和地址為: 10010B 
    MOV    B, #(NADDR+3) 
    CALL    OUTDATA 
    CLR    CS                         
    CALL    STATUS        ; 延時(shí)子程序 
    RET 
;========================================================== 
;名稱: 擦/寫允許(EWEN 指令) 
;功能: AT93CXX在上電復(fù)位后,芯片處于擦/寫不允許狀態(tài), 
;      EWEN 指令將芯片置為可編程狀態(tài),即可擦/寫 
;---------------------------------------------------------- 
EWEN:     
    SETB    CS         
    MOV    DPTR, #(10011B SHL (NADDR-2)) ;將10011B向左移((NADDR-2)位 
                ; EWEN 指令: 操作碼的地址為: 10011B 
    MOV    B, #(NADDR+3) 
    CALL    OUTDATA 
    CLR    CS         
    RET 
;========================================================== 
;名稱: 擦/寫禁止(EWDS 指令) 
;功能: 使用該指令可對(duì)寫入的數(shù)據(jù)進(jìn)行保護(hù)，操作步驟與擦／寫允許指令相同. 
;---------------------------------------------------------- 
EWDS: 
    SETB    CS                         
    MOV    DPTR, #(10000B SHL (NADDR-2)) 
    MOV    B, #(NADDR+3) 
    CALL    OUTDATA 
    CLR    CS         
    RET 
;========================================================== 
;延時(shí)子程序 
;---------------------------------------------------------- 
STATUS:     
    PUSH    B 
    SETB    DO        ; FLOAT PIN 
    SETB    CS         
    MOV    B, #220        ; 220 * 50 us = 11 ms             
EE40: 
    PUSH    B        ; 2 us 
    MOV    B, #22        ; 2 us 
    DJNZ    B, $        ; 2 us * 22 
    POP    B        ; 2 us 
    JB    DO, EE41     
    DJNZ    B, EE40         
    SETB    C         
    JMP    EE42         
EE41: 
    CLR    C         
EE42: 
    CLR    CS 
    POP    B 
    RET 
;========================================================== 
INDATA:     
    SETB    DO                         
    CALL    SHIN 
    JNB    SIZE, EE21    ; SIZE=0時(shí),8bit; SIZE=1時(shí),16bit 
    MOV    DATA_HI, A    ; SAVE HIGH BYTE 
                ; SIZE=1時(shí),16bit 
    CALL    SHIN 
EE21:                ; SIZE=0時(shí),8bit 
    MOV    DATA_LO, A    ; SAVE LOW BYTE 
    RET 
;========================================================== 
;讀一個(gè)字節(jié)子程序, 讀回的數(shù)據(jù)在A中 
;---------------------------------------------------------- 
SHIN: 
    PUSH    B 
    CLR    SK         
    MOV    B,#8         
EE30: 
    SETB    SK         
    NOP             
    MOV    C,DO         
    RLC    A         
    CLR    SK         
    DJNZ    B,EE30         
    POP    B 
    RET 
;========================================================== 
;向AT93CXX 寫入地址 
;---------------------------------------------------------- 
OUTDATA: 
    PUSH    B 
    MOV    A,B         
    CLR    C         
    SUBB    A,#8         
    JC    EE6         
    JZ    EE5                 
    MOV    B,A         
    CLR    C         
    SUBB    A,#8         
    JC    EE2         
    JNZ    EE9         
    MOV    A,DPH     
    JMP    EE4 
EE2: 
    PUSH    B         
    MOV    A,DPH         
EE3: 
    RR    A         
    DJNZ    B,EE3         
    POP    B         
EE4: 
    CALL    SHOUT         
    MOV    B,#8         
EE5: 
    MOV    A, DPL     
    JMP    EE8 
EE6: 
    PUSH    B         
    MOV    A,DPL         
EE7: 
    RR    A         
    DJNZ    B,EE7         
    POP    B         
EE8: 
    CALL    SHOUT 
EE9: 
    SETB    DO         
    POP    B 
    RET 
;========================================================== 
; 寫一個(gè)字節(jié)子程序 
; 入口: 寫入數(shù)據(jù)須事先存入A中. 
;---------------------------------------------------------- 
SHOUT:     
EE50: 
    CLR    SK         
    RLC    A         
    MOV    DI,C         
    NOP            ; DELAY MIN 400 ns 
    SETB    SK         
    DJNZ    B,EE50         
    CLR    SK         
    RET 
;========================================================== 
;========================================================== 

END